Lotus Notes Send EMail from VB or VBA
This ORIGINAL piece of code shows you how to mail direct from VBA or VB into lotus notes. Requires Lotus Notes Client 4.5.x or later is installed on your system.
As far as I can tell the Lotus Notes objects all have to be late bound otherwise you get errors. I have never found out the reason for this (the only thing I can think of is there is an error in the lotus notes api). Feel free to use this code,but if you do use it,please put a link from your site if you have one. Don't as many people have done blantantly rip it off and call it your own. I'm watching you and it's going to bite.
Point of note. Certain versions of 4.x client handle differently. If you get an error on the line MailDoc.CREATERICHTEXTITEM ("Attachment"),then try removing that line. In later versions of notes API this task is carried out by the previous line. Earlier versions required the call afterwards. Can't seem to fathom out the reason for that.
'Public Sub SendNotesMail(Subject as string,attachment as string,
'recipient as string,bodytext as string,saveit as Boolean)
'This public sub will send a mail and attachment if neccessary to the
'recipient including the body text.
'Requires that notes client is installed on the system.
Public Sub SendNotesMail(Subject As String,Attachment As String,Recipient As String,BodyText As String,SaveIt As Boolean)
'Set up the objects required for Automation into lotus notes
Dim Maildb As Object 'The mail database
Dim UserName As String 'The current users notes name
Dim MailDbName As String 'THe current users notes mail database name
Dim MailDoc As Object 'The mail document itself
Dim AttachME As Object 'The attachment richtextfile object
Dim Session As Object 'The notes session
Dim EmbedObj As Object 'The embedded object (Attachment)
'Start a session to notes
Set Session = CreateObject("Notes.NotesSession")
'Next line only works with 5.x and above. Replace password with your password
Session.Initialize("password")
'Get the sessions username and then calculate the mail file name
'You may or may not need this as for MailDBname with some systems you
'can pass an empty string or using above password you can use other mailboxes.
UserName = Session.UserName
MailDbName = Left$(UserName,1) & Right$(UserName,(Len(UserName) - InStr(1,UserName," "))) & ".nsf"
'Open the mail database in notes
Set Maildb = Session.GETDATABASE("",MailDbName)
If Maildb.ISOPEN = True Then
'Already open for mail
Else
Maildb.OPENMAIL
End If
'Set up the new mail document
Set MailDoc = Maildb.CREATEDOCUMENT
MailDoc.Form = "Memo"
MailDoc.sendto = Recipient
MailDoc.Subject = Subject
MailDoc.Body = BodyText
MailDoc.SAVEMESSAGEONSEND = SaveIt
'Set up the embedded object and attachment and attach it
If Attachment <> "" Then
Set AttachME = MailDoc.CREATERICHTEXTITEM("Attachment")
Set EmbedObj = AttachME.EMBEDOBJECT(1454,"",Attachment,"Attachment")
MailDoc.CREATERICHTEXTITEM ("Attachment")
End If
'Send the document
MailDoc.PostedDate=Now() 'Gets the mail to appear in the sent items folder
MailDoc.SEND 0,Recipient
'Clean Up
Set Maildb = Nothing
Set MailDoc = Nothing
Set AttachME = Nothing
Set Session = Nothing
Set EmbedObj = Nothing
End Sub |
|
If you want to send a message to more than one person or copy or blind carbon copy the following may be of use to you.
MailDoc.sendto = Recipient
MailDoc.CopyTo = ccRecipient
MailDoc.BlindCopyTo = bccRecipient
|
Also for multiple email addresses you just set MailDoc.sendto to an array of variants each of which will receive the message. So
Dim recip(25) as variant
recip(0) = "emailaddress1"
recip(1) = "emailaddress2" e.t.c
maildoc.sendto = recip |
Thanks must go out to
Mark Austin,Long Beach,California
assisted by the great folks at
www.deja.com & www.notes.net
for his help in finding the way to get the mailto appear in the sent items folder and his array method of sending the mail to more than one person. （编辑：李大同）
【声明】本站内容均来自网络，其相关言论仅代表作者个人观点，不代表本站立场。若无意侵犯到您的权利，请及时与联系站长删除相关内容!
|
