delphi – 调用从接口和另一个祖先继承的类的方法

基本的东西是：

>对于任意数量的类,您都有一个共同的祖先类(或表单).祖先声明了类以某种方式专门化的虚方法.
>使用任意数量的方法声明接口.不要忘记在界面中添加GUID.
>扩展表单声明以实现声明的接口,将接口添加到类声明并添加声明的方法.
>你现在可以：

>使用祖先类多态调用任何虚方法
>询问任何表单是否实现了接口,如果是,请检索对它的接口引用并调用任何接口方法.所有这些都可以使用supports功能完成.

我做了一个我能想到的最简单的例子,使用视觉继承表单和简单的界面.该示例的摘录如下：

共同的祖先类：

type
  TServerForm = class(TForm)
  private
    { Private declarations }
  public
    { Public declarations }
    procedure Method1; virtual;
  end;

界面：

type
  IMyInterface = interface
  ['{B7102C7E-F7F6-492A-982A-4C55CB1065B7}']
    procedure Method2;
  end;

孩子形成：

这个继承自TServerForm并实现接口

type
  TServerForm3 = class(TServerForm,IMyInterface)
  public
    procedure Method1; override;
    procedure Method2;
  end;

这个只是继承自TServerForm

type
  TServerForm4 = class(TServerForm)
  public
    procedure Method1; override;
  end;

这个直接从TForm继承并实现接口

type
  TNoServerForm = class(TForm,IMyInterface)
  public
    procedure Method2;
  end;

所有表单都是自动创建的,然后,我有这个代码来调用另一个表单上的几个OnClick for按钮上的方法(应用程序示例的主要形式)：

要基于多态调用虚方法：

procedure TForm6.Button1Click(Sender: TObject);
var
  I: Integer;
begin
  for I := 0 to Screen.FormCount - 1 do
  begin
    if (Screen.Forms[I] is TServerForm) then
      TServerForm(Screen.Forms[I]).Method1;
  end;
end;

要根据接口的实现调用该方法：

procedure TForm6.Button2Click(Sender: TObject);
var
  I: Integer;
  Intf: IMyInterface;
begin
  for I := 0 to Screen.FormCount - 1 do
  begin
    if Supports(Screen.Forms[I],IMyInterface,Intf) then
      Intf.Method2;
  end;
end;

方法只显示消息,一切正常：

procedure TServerForm3.Method2;
begin
  ShowMessage(ClassName + '.Method2');
end;