Groovy闭包深入学习

基本按原文作者思路来，只是我比原博主菜很多，所以要增加一些解释。

原文链接：http://lggege.iteye.com/blog/365242

1.?定义和执行闭包

def one = { num1,num2 ->
	println "param is: $num1 & $num2"
}
one(2,3)       // 简便写法。输出 param is: 2 & 3
one 2,3        // 省略()的等效写法

one.call(2,3) // 使用call方法
one.call 2,3  // 省略()等效写法

注意：
a) 闭包自身的定义写法。在参数与具体代码执行端间的分隔符是 ->，老版本的是|
b) 使用call方法，或简便写法。
c) 由于groovy可省略()，而引发的众多等效写法。
d) 单参数，可省略书写参数，在闭包内使用it变量引用参数。

2. 闭包作为返回值

def makeClosure(name) {
    return {
        println "Hello ${name}"
    }
}

println makeClosure(‘World’) // 请问输出结果? 

a) 返回的是一个代码块，也就是说，闭包可以理解为一个代码块。

b) 输出结果是ConsoleScript19$_makeClosure_closure1@26e02b68

3.?闭包作为参数传递 ??

def run(closure) {
	closure.call()
}

one = { println 'Hello,World!' }

run(one)

a) 有点像javaScript，function是一个对象，可以作为参数

4.?闭包使用外部变量

class OneClosure {
	def static execute(closure) {
		def word = 'Cool' // !!! 注意不使用def的输出结果，理解方式使用引用
		closure('Grails')
	}
	
	public static void main(args) {
		def word = 'Hello'
		
		def two = {param -> println "${word} ${param}"}
		two('Groovy') // 输出 Hello Groovy
		
		word = 'Wow'
		two('Java') // 输出 Wow Java
		
		OneClosure.execute(two) // 输出 Wow Grails，而不是Cool Grails
	}
}

a) 闭包可使用（引用）闭包外部定义的变量

b) 变量的定义必须在闭包的上面，否则有groovy.lang.MissingPropertyException异常。

c) 注意在代码标记出，如果不使用def的输出差异。具体解释可使用引用来理解。在一个闭包被定义后，使用的是闭包定义所在的外部对象，对于使用的外部对象的引用一直都不会改变（无论是否被作为参数传递）。

可以这么理解：其实闭包在作为参数传递的时候? 传递的不仅仅只是方法，还有这个方法外面的现场。

所以.net的委托在传递的同时，其实不仅仅传递了方法，也传递了方法外面的对象。最简单的就是这个传递的方法的外面的一层属性等。

5.?使用闭包实现单方法接口

interface Test {
    def one()
}

def test = {println 'one'} as Test

test.one()

a) 使用关键字as

6.?使用闭包实现多方法接口

interface Test {
    def one()
    def two()
}

def test = [
    one: {println 'one'},two: {println 'two'}
    ] as Test

test.one()
test.two()

a) 使用关键字as

b) 使用Map,key为接口名,value为闭包