xml – XSLT – 复制所有其他节点,添加1个新节点

发布时间：2020-12-16 23:31:38 所属栏目：百科来源：网络整理

导读：我创建了一个XSLT,我想知道如何在一组标签之间复制所有节点,并在底部添加另一个标签.我创建了XSLT,它具有确定要添加哪个标记以及应该调用的标记的所有逻辑.但是我现在遇到的问题是我无法复制所有其他标签.以下是有问题的文件： XSLT ?xml version="1.0" enco

我创建了一个XSLT,我想知道如何在一组标签之间复制所有节点,并在底部添加另一个标签.我创建了XSLT,它具有确定要添加哪个标记以及应该调用的标记的所有逻辑.但是我现在遇到的问题是我无法复制所有其他标签.以下是有问题的文件：

XSLT

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    version="1.0">
    <xsl:output method="xml" indent="yes"/>

    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="/csvImportSchema">
        <csvImportSchema>
            <xsl:for-each select="payload">
                <payload>
                    <xsl:copy-of select="@*"/>
                    <xsl:variable name="ean">
                        <xsl:value-of select="ean"/>
                    </xsl:variable>
                    <xsl:for-each select="../product">
                        <xsl:if test="ean = $ean">
                            <productId><xsl:value-of select="article"/></productId>
                        </xsl:if>
                    </xsl:for-each>
                </payload>
            </xsl:for-each>
        </csvImportSchema>
    </xsl:template>

</xsl:stylesheet>

INPUT

<?xml version="1.0" encoding="UTF-8"?>
<csvImportSchema>
    <payload>
        <test>1</test>
        <test2>2</test2>
        <test3>3</test3>
        <ean>2222222222</ean>
        <productId/>
    </payload>
    <product>
        <article>722619</article>
        <ean>2222222222</ean>
    </product>
</csvImportSchema>

当前输出

<?xml version="1.0" encoding="utf-8"?>
<csvImportSchema>
    <payload>
        <productId>722619</productId>
    </payload>
</csvImportSchema>

期望的输出

<?xml version="1.0" encoding="UTF-8"?>
<csvImportSchema>
    <payload>
        <test>1</test>
        <test2>2</test2>
        <test3>3</test3>
        <ean>2222222222</ean>
        <productId>722619</productId>
    </payload>
</csvImportSchema>

解决方法

这个简短而简单的转变：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match="productId">
  <productId>
    <xsl:value-of select="../../product/article"/>
  </productId>
 </xsl:template>
 <xsl:template match="product"/>
</xsl:stylesheet>

当应用于提供的XML文档时：

<csvImportSchema>
    <payload>
        <test>1</test>
        <test2>2</test2>
        <test3>3</test3>
        <ean>2222222222</ean>
        <productId/>
    </payload>
    <product>
        <article>722619</article>
        <ean>2222222222</ean>
    </product>
</csvImportSchema>

产生想要的,正确的结果：

<csvImportSchema>
   <payload>
      <test>1</test>
      <test2>2</test2>
      <test3>3</test3>
      <ean>2222222222</ean>
      <productId>722619</productId>
   </payload>
</csvImportSchema>

说明：

> identity rule副本“按原样”复制选择执行的每个节点.>覆盖模板匹配产品从输出中“删除”此元素(通过其空体).>另一个重写模板与productId匹配,并使用取自product / article的文本节点子项生成此元素.

（编辑：李大同）

【声明】本站内容均来自网络，其相关言论仅代表作者个人观点，不代表本站立场。若无意侵犯到您的权利，请及时与联系站长删除相关内容!