asp.net – 通过反射获取其getter具有可选值的属性的值

发布时间：2020-12-16 03:27:06 所属栏目：asp.Net 来源：网络整理

导读：我正在检索控件的几个属性.以下是我用于检索属性的方法(使用PropertyInfo类型的pinfo)： value = pinfo.GetValue(obj,nothing) 这很好,但现在我面临一个具有可选值的属性,并且我收到一条错误消息,告诉我参数的数量不正确.所以我改变了我的代码： Dim index A

我正在检索控件的几个属性.以下是我用于检索属性的方法(使用PropertyInfo类型的pinfo)：

value = pinfo.GetValue(obj,nothing)

这很好,但现在我面临一个具有可选值的属性,并且我收到一条错误消息,告诉我参数的数量不正确.所以我改变了我的代码：

Dim index As Object() = {Nothing}
value = pinfo.GetValue(obj,index)

此时,我没有收到任何错误消息,但此代码未检索到良好的值.它只有在我用属性访问器提供的默认值替换Nothing时才有效…

但我事先并不知道这个默认值是多少！并且此代码位于一个函数中,该函数检索没有可选值的属性,因此我无法更改代码,尤其是对于一种情况或另一种情况.

任何的想法？我正在研究.NET 2.0

编辑：关于导致问题的案件的更精确

以下是导致问题的属性示例：

ReadOnly Property Foo(Optional ByVal Number As Integer = -1) As String
    Get
        If Number = -1 Then
            Return "Your number is the default number: " & Number
        Else
            Return "Your number is " & Number
        End If
    End Get
End Property

有了这种属性,上面的代码都没有检索到好的字符串.

我最好的猜测是尝试第一个代码用于一般目的,捕获相应的异常,然后动态检索参数的默认值(在这种情况下为Number)及其类型,以便我可以使用此默认值调用getValue.

那么,如何检索可选参数的默认值？

解决方法

这适用于可选参数：

ReadOnly Property Foo(Optional name As String = Nothing) As String
    Get
        If name Is Nothing Then
            Return "Hello World"
        Else
            Return "Hello " & name
        End If
    End Get
End Property


Dim pinfo As Reflection.PropertyInfo = Me.GetType().GetProperty("Foo")
Dim value As Object = pinfo.GetValue(Me,New Object() {"Tim"})  ' Hello Tim '
value = pinfo.GetValue(Me,New Object(){Nothing})               ' Hello World '

编辑：根据你的评论,整数不起作用,我还不知道如何在属性中获取可选参数的默认值.如果您知道它可以轻松传递它,但是否则会发生以下情况(注意Int32.MinValue是默认值而不是0)：

ReadOnly Property Foo(Optional age As Int32 = Int32.MinValue) As String
    Get
        If age = Int32.MinValue Then
            Return "I don't know how old i am"
        Else
            Return String.Format("I am {0} years old",age)
        End If
    End Get
End Property

Dim pinfo As Reflection.PropertyInfo = Me.GetType.GetProperty("Foo")
Dim value As Object = pinfo.GetValue(Me,New Object() {38})  ' I am 38 years old '
value = pinfo.GetValue(Me,New Object() {Nothing})           ' I am 0 years old '
value = pinfo.GetValue(Me,New Object() {Int32.MinValue})    ' I don't know how old i am '

编辑2：感谢@Rup现在我知道GetIndexParameters是缺失的部分.因此,以下应适用于任何类型的参数.

Dim pinfo As Reflection.PropertyInfo = Me.GetType.GetProperty("Foo")
Dim parameters() As Reflection.ParameterInfo = pinfo.GetIndexParameters()
Dim params(parameters.Length - 1) As Object
For i As Int32 = 0 To parameters.Length - 1
    Dim paramInfo As Reflection.ParameterInfo = parameters(i)
    If paramInfo.IsOptional Then
        params(i) = paramInfo.DefaultValue
    Else
        If paramInfo.ParameterType.IsValueType Then
            params(i) = Activator.CreateInstance(paramInfo.ParameterType)
        Else
            params(i) = Nothing
        End If
    End If
Next
Dim value As Object = pinfo.GetValue(Me,params)

（编辑：李大同）

【声明】本站内容均来自网络，其相关言论仅代表作者个人观点，不代表本站立场。若无意侵犯到您的权利，请及时与联系站长删除相关内容!