Perl6：将Match对象转换为JSON可序列化Hash

它与Christoph发布的内容几乎相同,但写得更加冗长(并且我添加了大量的注释以使其更容易理解)：

#| Fallback action method that produces a Hash tree from named captures.
method FALLBACK ($name,$/) {

    # Unless an embedded { } block in the grammar already called make()...
    unless $/.made.defined {

        # If the Match has named captures,produce a hash with one entry
        # per capture:
        if $/.hash -> %captures {
            make hash do for %captures.kv -> $k,$v {

                # The key of the hash entry is the capture's name.
                $k => $v ~~ Array 

                    # If the capture was repeated by a quantifier,the
                    # value becomes a list of what each repetition of the
                    # sub-rule produced:
                    ?? $v.map(*.made).cache 

                    # If the capture wasn't quantified,the value becomes
                    # what the sub-rule produced:
                    !! $v.made
            }
        }

        # If the Match has no named captures,produce the string it matched:
        else { make ~$/ }
    }
}

笔记：

>这完全忽略了位置捕获(即在语法内用()进行的捕获) – 仅使用命名捕获(例如< foo>或< foo = bar>)来构建哈希树.它可以修改为处理它们,具体取决于你想用它们做什么.请记住：

> $/.hash给出命名的捕获,作为Map.
> $/ .list给出位置捕获,作为List.
> $/.cap(或$/.对)给出命名和位置捕获,作为name => submatch和/或index =>子匹配对的序列.

>它允许您覆盖特定规则的AST生成,方法是在语法规则中添加{make …}块(假设您从不故意想要创建未定义的值),或者添加方法动作类的规则名称.