如何指定包含我接受的所有内容的Perl 6签名并排除其他所有内容？

class SomeClass {
    method something ( Int $n ) { 'Ran something' }
    }

put SomeClass.something: 137; # Ran something
put SomeClass.something: 137,:foo('bar'); # Ran something

class SomeClass {
    multi method something ( Int $n ) { 'Ran something' }
    multi method something ( Int $n,:$foo ) { "Ran $foo" }
    }

put SomeClass.something: 137;  # Ran
put SomeClass.something: 137,:foo('bar'); # Ran bar
put SomeClass.something: 137,:bar('foo'); # Ran

您正在谈论有关多方法调度最难掌握的事情之一.最重要的是要实现每个方法签名都有一个隐含的*％_(也就是一个slurpy哈希),如果没有指定的话.这意味着它将吃掉任何非特定的命名参数.

class A {
    method a() { dd %_ }  # %_ exists even if not specifically specified
}
A.a(:foo)   # {:foo}

您需要意识到的第二件事是,命名参数只能起到打破平局的作用.因此,如果有多个候选者具有相同的位置参数匹配集,MMD将使用第一个有效的候选者(考虑到所有意外的命名参数都被％_ sl)：

class A {
    multi method a(:$foo) { say "foo" }
    multi method a(:$bar) { say "bar" }
}
A.a(:bar)    # foo

这个看似意外的结果是由以下事实引起的：

>两个候选人具有相同数量的位置参数
>第一个候选匹配因为：$foo是可选的
>和：bar被隐含的*％_吃掉

为了使它更像您期望的工作,您需要将需要打破的候选项放入您希望它们触发的顺序,并使任何命名参数成为必需参数：

class A {
    multi method a(:$foo!) { say "foo" }
    multi method a(:$bar!) { say "bar" }
}
A.a(:bar)    # bar

如果您有候选者采用多个命名参数,它很快就会变得相当复杂,只要有一个使用％_的内省的方法,你可能会更好：

class A {
    method a() {
        if %_<foo> {
            say "foo"
        }
        elsif %_<bar> {
            say "bar"
        }
        else {
            die "None of the signatures matched"
        }
    }
}
A.a(:bar)    # bar

希望这会让事情更加清晰:-)