delphi – 动态列出项目中的所有表单

在评论中,哈米德要求找到一种找到未分配形式的方法.假设通过未分配,他意味着未实例化的表单,那么只有一种方法可以执行此操作,即迭代vcl流系统使用的类的注册表,以便在流式传输dfm时按名称实例化组件.

但是,IIRC,表单不会自动添加到注册表中.实际上,如果要基于其名称字符串实例化表单,则需要(ed)将它们自己添加到类注册表中. OP当然可以为他自己项目中的每个表单做到这一点.但是,这留下了一个问题,即流系统使用的类注册表是使用类单元的实现部分中的var实现的.因此不能从外部(轻松)迭代.

因此,解决方案是使用项目中所有表单单元的初始化部分,并将每个表单注册到“自己动手”的注册表中,并使用其名称和类,并让注册表提供迭代已注册表单的方法.这些方法可用于填充OP提到的列表框.

要获取表单上的TButtons,则需要实例化表单(它可能保持隐藏状态)并使用类似于sabri.arslan的答案的代码迭代组件以查找TButton实例.

实例化表单需要根据列表框中选择的表单名称从注册表中获取表单的类.

一个简单的roll-your-own表单注册表的示例：

unit Unit1;

interface

uses
  Classes,Forms,SysUtils
  ;

  procedure RegisterForm(aName: string; aClass: TFormClass);
  procedure ListForms(aNames: TStrings);
  function InstantiateForm(aName: string): TCustomForm;

implementation

var
  FormRegistry: TStringList;

procedure RegisterForm(aName: string; aClass: TFormClass);
begin
  FormRegistry.AddObject(aName,Pointer(aClass));
end;

procedure ListForms(aNames: TStrings);
var
  i: Integer;
begin
  for i := 0 to FormRegistry.Count - 1 do begin
    aNames.Add(FormRegistry[i]);
  end;
end;

function InstantiateForm(aName: string): TCustomForm;
var
  idx: Integer;
  frmClass: TFormClass;
begin
  Result := nil;
  idx := FormRegistry.IndexOf(aName);
  if idx > -1 then begin
    frmClass := TFormClass(FormRegistry.Objects[idx]);
    Result := frmClass.Create(nil);
  end;
end;

initialization
  FormRegistry := TStringList.Create;
  FormRegistry.Duplicates := dupError;
  FormRegistry.Sorted := True;
finalization
  FreeAndNil(FormRegistry);
end.