delphi – 具有不同签名的功能指针(例如：带有默认值的可选参数)

但是您可以使用函数引用和匿名方法来创建此类函数指针 – 函数适配器.

type
  fnA = function(const sName: AnsiString): integer;
  fnB = function(const sName: AnsiString; const tOptional: TObject); integer;

  fnRef = reference to function(const sName: AnsiString; const tOptional: TObject): integer;

  fnBridge = record 
     Bridge: fnRef;
     class operator Implicit(fn: fnA): fnBridge;
     class operator Implicit(fn: fnB): fnBridge;
  end;

class operator fnBridge.Implicit(fn: fnA): fnBridge;
begin
  Result.Bridge := 
     function(const sName: AnsiString; const tOptional: TObject): integer
     begin
       Result := fn(sName); 
     end;
end;

class operator fnBridge.Implicit(fn: fnB): fnBridge;
begin
  Result.Bridge := 
     function(const sName: AnsiString; const tOptional: TObject): integer
     begin
       Result := fn(sName,tOptional); 
     end;
end;

function A(const sName: AnsiString): integer; 
begin Result := Length(sName) end;

function B(const sName: AnsiString; const tOptional: TObject): integer; 
begin Result := Length(sName) - Length(tOptional.ClassName) end;

function Consumer (const Param1,Param2: integer; const Action: fnBridge): integer;
begin
  Result := Param1 + Param2 * Action.Bridge('ABCDE',Application);
end;

....
  ShowMessage( IntToStr( Consumer(10,20,A) ));
  ShowMessage( IntToStr( Consumer(10,B) ));

PS：由于未指定Delphi版本,这意味着任何Delphi版本的答案都适合.从Delphi 2009及更高版本开始,此方法应该是hany版本.

PPS：对具有捕获变量的函数的引用在内部实现为TInterfacedObject后代.总的来说,这只是使用“高阶函数”的“战略模式”的简化案例

> http://en.wikipedia.org/wiki/Strategy_pattern
> http://en.wikipedia.org/wiki/Higher-order_function