delphi – 如何使用TIdIMAP4登录Gmail帐户并获取邮箱中的邮件数

在代码中它可能如下所示(此代码需要OpenSSL,因此不要忘记将libeay32.dll和ssleay32.dll库放到项目可见的路径中;您可以在不同版本和平台上下载Indy的OpenSSL库from here )：

uses
  IdIMAP4,IdSSLOpenSSL,IdExplicitTLSClientServerBase;

function GetGmailMessageCount(const UserName,Password: string): Integer;
var
  IMAPClient: TIdIMAP4;
  OpenSSLHandler: TIdSSLIOHandlerSocketOpenSSL;
begin
  Result := 0;
  IMAPClient := TIdIMAP4.Create(nil);
  try
    OpenSSLHandler := TIdSSLIOHandlerSocketOpenSSL.Create(nil);
    try
      OpenSSLHandler.SSLOptions.Method := sslvSSLv3;
      IMAPClient.IOHandler := OpenSSLHandler;
      IMAPClient.Host := 'imap.gmail.com';
      IMAPClient.Port := 993;
      IMAPClient.UseTLS := utUseImplicitTLS;
      IMAPClient.Username := UserName;
      IMAPClient.Password := Password;
      IMAPClient.Connect;
      try
        if IMAPClient.SelectMailBox('INBOX') then
          Result := IMAPClient.MailBox.TotalMsgs;
      finally
        IMAPClient.Disconnect;
      end;
    finally
      OpenSSLHandler.Free;
    end;
  finally
    IMAPClient.Free;
  end;
end;

procedure TForm1.ConnectButtonClick(Sender: TObject);
begin
  ShowMessage('Total count of messages in inbox: ' +
    IntToStr(GetGmailMessageCount('UserName@gmail.com','Password')));
end;

您可以选择下载包含用于32位应用程序的i386平台的OpenSSL v1.0.1c库的demo project(在Delphi 2009中编译).