unit-testing – 如何在grails中单元测试服务时模拟请求

我为此做了一个简单的规范,并且当它不起作用时非常惊讶！所以这结果是一个非常有趣的问题.经过一番调查,我发现在这种特殊情况下,有一些陷阱需要注意.

>当您检索请求对象RCH.requestAttributes.request时,您通过未实现getRequest()方法的接口RequestAttributes这样做.如果返回的对象实际上具有此属性,则在groovy中完全正常,但在spock中模拟RequestAttributes接口时将无法工作.因此,您需要模拟实际具有此方法的接口或类.
>我第一次尝试解决1.,是将mock类型更改为ServletRequestAttributes,它具有getRequest()方法.但是,这种方法是最终的.当使用最终方法的值来存储模拟时,简单地忽略存根值.在这种情况下,返回null.

通过为此测试创建一个名为MockRequestAttributes的自定义接口,并在规范中将此接口用于Mock,可以轻松克服这两个问题.

这导致以下代码：

import org.springframework.web.context.request.RequestContextHolder

// modified for testing
class AddressService {

    def localAddress
    def contentType

    def update() {
        def request = RequestContextHolder.requestAttributes.request
        localAddress = request.localAddr
        contentType = request.contentType
    }
}

import org.springframework.web.context.request.RequestAttributes
import javax.servlet.http.HttpServletRequest

interface MockRequestAttributes extends RequestAttributes {
    HttpServletRequest getRequest()
}

import org.springframework.web.context.request.RequestContextHolder
import spock.lang.Specification

import javax.servlet.http.HttpServletRequest

class MockRequestSpec extends Specification {

    def "let's mock a request"() {
        setup:
        def requestAttributesMock = Mock(MockRequestAttributes)
        def requestMock = Mock(HttpServletRequest)
        RequestContextHolder.metaClass.'static'.getRequestAttributes = {->
            requestAttributesMock
        }

        when:
        def service = new AddressService()
        def result = service.update()

        then:
        1 * requestAttributesMock.getRequest() >> requestMock
        1 * requestMock.localAddr >> '127.0.0.1'
        1 * requestMock.contentType >> 'text/plain'
        service.localAddress == '127.0.0.1'
        service.contentType == 'text/plain'

        cleanup:
        RequestContextHolder.metaClass = null
    }

}