加入收藏 | 设为首页 | 会员中心 | 我要投稿 李大同 (https://www.lidatong.com.cn/)- 科技、建站、经验、云计算、5G、大数据,站长网!
当前位置: 首页 > 百科 > 正文

使用LINQ对属性进行VB XML查询

发布时间:2020-12-17 07:29:33 所属栏目:百科 来源:网络整理
导读:我正在尝试学习LINQ并且有一个关于使用VB查询 XML的问题. 我的XML: Procedure-Text A ID="marker1"/ADo This Procedure /Procedure-Text Procedure-Text A ID="marker2"/ADo That Procedure /Procedure-Text 如何指定查询以仅获取具有ID属性marker2的过程文
我正在尝试学习LINQ并且有一个关于使用VB查询 XML的问题.

我的XML:

<Procedure-Text>
    <A ID="marker1"></A>Do This Procedure
 </Procedure-Text>
 <Procedure-Text>
    <A ID="marker2"></A>Do That Procedure
 </Procedure-Text>

如何指定查询以仅获取具有ID属性marker2的过程文本?换句话说,我想要一个结果字符串,表示执行该程序.

谢谢

解决方法

使用VB XML文字:

Dim marker2 = From x In data...<Procedure-Text> _
              Where x.<A>.@ID = "marker2" _
              Select x

三点语法产生xml元素的“所有后代”,即数据……< Procedure-Test>将产生< Procedure-Test>的列表内部数据标签

XML文字上的点语法表示“第一个后代”,因此x.< A>将产生< A>的第一次出现.在里面x.其中x现在是< Procedure-Test>的实例.

现在你有了所需的< A>使用@attr属性选择器将其id与字符串进行比较是微不足道的.如果< A>的ID属性,则< A>.@ ID =“marker2”将评估为True.标签等于“marker2”

所以x.< A>.@ ID表示“x内的第一个< A>标记的ID属性”

你想要< Procedure-Text>元素,因此您指定选择x

完整示例:

Sub Main()

    Dim data = <doc>
                   <Procedure-Text>
                       <A ID="marker1"></A>Do This Procedure
                   </Procedure-Text>
                   <Procedure-Text>
                       <A ID="marker2"></A>Do That Procedure
                   </Procedure-Text>
               </doc>

    Dim marker2 = From x In data...<Procedure-Text> _
                  Where x.<A>.@ID = "marker2" _
                  Select x

    ' prints the second procedure-text element
    Console.WriteLine(marker2.FirstOrDefault().ToString())

    Console.ReadKey()

End Sub

(编辑:李大同)

【声明】本站内容均来自网络,其相关言论仅代表作者个人观点,不代表本站立场。若无意侵犯到您的权利,请及时与联系站长删除相关内容!

    推荐文章
      热点阅读