使用XSLT根据节点数转换XML

发布时间：2020-12-16 22:57:13 所属栏目：百科来源：网络整理

导读：我希望根据元素的数量转换节点.即5,然后关闭节点并重新打开一个新节点. ?见下面的例子 root branch foobar/foo foobar2/foo foobar3/foo foobar4/foo foobar5/foo foobar6/foo foobar7/foo /branchroot 应该成为 root branch foobar/foo foobar2/foo foobar3

我希望根据元素的数量转换节点.即5,然后关闭节点并重新打开一个新节点.
?见下面的例子

<root>
  <branch>
    <foo>bar</foo>
    <foo>bar2</foo>
    <foo>bar3</foo>
    <foo>bar4</foo>
    <foo>bar5</foo>
    <foo>bar6</foo>
    <foo>bar7</foo>
  </branch>
<root>

应该成为

<root>
  <branch>
    <foo>bar</foo>
    <foo>bar2</foo>
    <foo>bar3</foo>
    <foo>bar4</foo>
    <foo>bar5</foo>
   <branch>
   </branch>
    <foo>bar6</foo>
    <foo>bar7</foo>
  </branch>
<root>

请帮助您了解如何在XSLT中完成此操作.

解决方法

I.这个XSLT 1.0转换：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="/*">
  <root>
   <xsl:apply-templates/>
  </root>
 </xsl:template>

 <xsl:template match="foo[position() mod 5 = 1]">
  <branch>
    <xsl:copy-of select=
     ". | following-sibling::*[not(position() > 4)]"/>
  </branch>
 </xsl:template>
 <xsl:template match="text()"/>
</xsl:stylesheet>

当应用于提供的XML文档(更正为格式良好)时：

<root>
    <branch>
        <foo>bar</foo>
        <foo>bar2</foo>
        <foo>bar3</foo>
        <foo>bar4</foo>
        <foo>bar5</foo>
        <foo>bar6</foo>
        <foo>bar7</foo>
    </branch>
</root>

产生想要的,正确的结果：

<root>
   <branch>
      <foo>bar</foo>
      <foo>bar2</foo>
      <foo>bar3</foo>
      <foo>bar4</foo>
      <foo>bar5</foo>
   </branch>
   <branch>
      <foo>bar6</foo>
      <foo>bar7</foo>
   </branch>
</root>

说明：

这是“位置分组”的情况,其中组的每个起始元素是5元组中的第一个(因此其位置满足：position()mod 5 = 1.

II. XSLT 2.0解决方案：

<xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="/*">
  <root>
    <xsl:for-each-group select="*/*"
         group-adjacent="(position() -1) idiv 5">
          <branch>
            <xsl:sequence select="current-group()"/>
          </branch>
    </xsl:for-each-group>
  </root>
 </xsl:template>
</xsl:stylesheet>

当这个XSLT 2.0转换应用于同一个XML文档(上面)时,会生成相同的想要的正确结果.

说明：

正确使用具有组相邻属性和current-group()功能的<xsl:for-each-group> XSLT 2.0指令.

（编辑：李大同）

【声明】本站内容均来自网络，其相关言论仅代表作者个人观点，不代表本站立场。若无意侵犯到您的权利，请及时与联系站长删除相关内容!