ActionScript 3.0系列教程(4)：爽快使用XML
为什么放弃AS2.0选择AS3.0?如果只允许我说三个理由。那么AS3.0对XML的近乎完美的支持绝对是其中一个。
简单说说AS3.0中对于XML支持的不同吧：
.AS2.0对XML的支持勉勉强强，将就着可以用。而AS3.0中对XML的支持是全方位的，极其强大和灵活的。
AS2.0对XML的支持不是内建的(build-in)，也并非基于ECMAScript for XML(E4X)标准。而AS3.0中对XML的支持符合E4X标准，它的设计有三个优点：
1. 简易。包括操作和可读性。你会发现AS3.0中对于XML的操作犹如对一个普通Object对象一样浅显易懂。语句非常浅白流畅。
2. 连续性。其各个功能的设计和AS3.0其余的部分思想一致，易于理解。
3. 熟悉。操作符和操作逻辑对我们来说都相当熟悉易用。
在AS2.0时代，为了解决这部分的问题
效率。
效率包括两方面，开发效率，和代码执行效率。开发效率的论述见上。AS3.0对于XML的执行效率远远高过没有内建XML支持的AS2.0。
XML的输入
在AS2.0时代，在代码行中输入XML代码是一种痛苦。如果不是从文件中读取，那么我们就要忍受一长串挤在一块儿的字符串。
而在AS3.0中，太简单了。直接按照XML的内容输即可，想换行就换行，想Tab就Tab，就一个字，爽。
新建一个fla,选中第一帧，F9打开动作面板，输入如下代码：
? //http://www.kingda.org
? //例1
? var kingdaXML:XML =
? <tutorial>
? <item id='1'>
? <level>2</level>
? <title>?First touch of Flash 9</title>
? </item>
? <item id='2'>
? <level>3</level>
? <title>?Binding Classes</title>
? </item>
? <item id='3'>
? <level>4</level>
? <title>Document Class</title>
? </item>
? </tutorial>
? trace (kingdaXML.item[1].level);? //output:3
? //例2
? var kS:String = "<root><txt>this is a test</txt></root>";
? var kXML:XML = new XML(kS);
? trace (kXML.txt); //output:this is? a test;
?
例1中注意到没，直接写XML内容在后面，想换行就换行，想tab就tab，多爽。不想AS2.0中写string时，换个行就不行了。
写完这一句后，我们所写出的类似于string的形式立刻就被Flash理解成了XML对象了，所以我们马上就可以用"."操作符来访问相应的属性。本例中访问了第2个item节点的level值。
这么简便直观的访问方式是不是比 AS2.0中那千遍一律的childNodes要好得多？
不过要注意，最后可以加";"结束。但我为了XML的视觉美观没有加。这个没有关系，编译时不会考虑这一点。
事实上只要你喜欢，AS1.0,2.0,3.0中语句结束都可以不加";"号。但是这并不是一个好的编程习惯，更不符合严谨的自我语法要求。因此我建议，除了XML可以不加外，其余的都应该加，呵呵。
例2展示了如何将一个包含了XML内容的字符串转换成XML对象。用的是XML的构造函数转换的。
AS3更有趣的是，可以使用已有的变量来直接构造XML，带来方便的编程特性。如下例。
? var rootNodeName?:String = "site";
? var subNodeName??:String = "orgin";
? var subNodeContent?:String = "Kingda's Blog";
? var attributeName?:String = "url"
? var attributeValue?:String = "http://www.kingda.org";
? var extXML:XML =
? <{rootNodeName} {attributeName}={attributeValue}>
? <{subNodeName}>{subNodeContent}</{subNodeName}>
? </{rootNodeName}>;
? trace (extXML.toString());
? /*output:
? <site url="http://www.kingda.org">
? <orgin>Kingda's Blog</orgin>
? </site>
? */
要点就是要把变量用"{}"括起来，并且设置属性时不要再加引号了。
XML的外部读取
包括读取外部xml文件，和通过URL读取xml。AS3.0中不像2.0那样集成了一个load()。
AS3.0在架构上就设计了所有与外部打交道的都由URLrequest对象来进行，数据都由URLloader对象来接受。这个我们会在下一部分教程详细讲解。这一次只要知道这样的架构设计是深思熟虑，且简洁优美的即可。
? var myXML:XML = new XML();
//初始化XML地址，可以是本地的"xxx.xml"，也可以是如下的URL地址。
? var XML_URL:String = "http://www.kingda.org/blog/index.xml";?????? //我的Blog RSS Feed
var myXMLURL:URLRequest = new URLRequest(XML_URL);
? var myLoader:URLLoader = new URLLoader(myXMLURL);
//添加装载完成侦听器,
? //Event.COMPLETE的值是"complete",直接用此字符串也可以。
? myLoader.addEventListener(Event.COMPLETE,xmlLoaded);
function xmlLoaded(evtObj:Event) {
? myXML = XML(myLoader.data);
? trace("数据装载完成.");
? trace (myXML);
? }
XML的操作
1.查询
//显示level为4的节点的title值
? trace (kingdaXML.item.(level == 4).title);
? //output：Document Class
//显示level>2的节点的title值，本处结果大于1，所以是一个XML Array。
? trace (kingdaXML.item.(level > 2).title);
? /*output:
? <title>Binding Classes</title>
? <title>Document Class</title>
? */
//使用属性用@开头即可。真方便。
? trace (kingdaXML.item.(level > 2).@id);
? //output:23
? //这儿要注意，实际上是2,3。一个Array.
//也可以用属性来做判断
? trace (kingdaXML.item.(@id > 1).title);
2.添加或者修改属性
方便的不能再方便，直接写即可。爽翻天啊。
? //把id == 1的节点level值改为2
? kingdaXML.item.(@id==1).level = 2;
? //把id==1的节点添加一个属性 page
? kingdaXML.item.(@id==1).page = 100;
? trace (kingdaXML.item.(@id==1));
3.按某条件插入节点
? var newNode1:XML = <item id='2.5'><level>0</level><title>None</title></item>
? var newNode2:XML = <item id='1.5'><level>0</level><title>None</title></item>
? //把newNode1插入到id==2的节点后面
? kingdaXML = kingdaXML.insertChildAfter(kingdaXML.item.(@id==2),newNode1);
//把newNode1插入到id==2的节点前面
? kingdaXML = kingdaXML.insertChildBefore(kingdaXML.item.(@id==2),newNode2);
? trace (kingdaXML);
XML的高级操作
常用的操作上面已经介绍的很清楚了。高级操作则是留给对XML应用更深的兄弟们。
几点注意：
1.在AS3.0中， XML类的ignoreWhitespace默认为true。
2.AS3.0支持对comments的直接操作。但默认:
? XML.ignoreComments = false;
? var kingdaXML:XML =
? <item>
? <!-- comment? 1-->
? <!-- comment? 2-->
? </item>;
? trace(kingdaXML.toXMLString());? //默认为true时，不会显示comment的
访问comment用
? trace(kingdaXML.comments()[1].toXMLString());?
3.XML支持克隆。
使用copy()可以得到一份现有XML的值拷贝。
? var kingdaCopy:XML = kingdaXML.copy();
对kingdaCopy操作就不会影响kingdaXML对象了。
4.极有用的descendants函数返回一个XMLList对象，包括所有的子节点。
设ignoreComments = false;和ignoreProcessingInstructions ＝ false后，连comments和process instructions也会包含在这个XMLList对象中。
运用示例如下：
? XML.ignoreComments = false;
? var xml:XML =
? <body>
? <!-- comment -->
? text1
? <a>
? <b>text2</b>
? </a>
? </body>;
? trace(xml.descendants("*").length()); // 5
? trace(xml.descendants("*")[0]); // // <!-- comment -->
? trace(xml.descendants("*")[1].toXMLString()); // text1
? trace(xml.descendants("a").toXMLString()); // <a><b>text2</b></a>
? trace(xml.descendants("b").toXMLString()); // <b>text2</b>
还有太多的XML有用操作功能了(如对namespace的操作)。用到时再去翻参考书吧。
以上的介绍可以满足绝大部分运用了。
对了AS2.0已有的XML类，在3.0中变成了XMLDocument类，使用方法不变。便于AS2.0程序移植。其余不推荐。
